$ k6ese   output k6rot effects in sol 101, 103
$ mag  November 14, 2001
compile semg list $
$alter 117 $ after kgg(Kjjz) available, rerun emg-ema again with k6 turned off
alter 'ema.*kjjz,' $
type parm,,rs,n,k6rotz=0.0 $
message //'input value of k6rot is'/k6rot $
if (k6rot><0.0) then $
  EMG      EST,CSTMS,MPTS,DIT,,,ETT,,DEQATN,DEQIND,BGPDTS,GPSNTS,           
   ECTAS,EPTA,EHTA,DITID/                                           
   KELM6,KDICT6, , , , /                                
   S,N,NOKGG6/0/0/ //                       
   COUPMASS///////////K6ROTz $   also purge damping, mass outputs 
  EMA      GPECT,KDICT6,KELM6,BGPDTS,SILS,CSTMS,KDICTP,KELMP/                    
                          KJJZ6, $ STIFFNESS with k6 removed
  Add kjjz,kjjz6/kgg6//-1.0 $ only k6 effects present in kgg6                                                 
  Add kelm,kelm6/kelmdiff//-1.0  $
Else 
  Message //'ufm.  k6rot must be non-zero to use this alter.' $
  Exit $
Endif $
Norm kelmdiff/scr6///s,n,maxk6 $
If (maxk6<1.e-10) then $
  Message //'ufm.  largest k6rot term is negligible, of size'/maxk6$
  Message //'add elements that have k6rot capability to use this alter' $
  Exit $
Else $
  Call dbstore kgg6,kelmdiff,,,//seid/0/'     '/0 $
Endif $

Compile super3 list $
Alter 'call.*sedisp' $ location ok for sol 101,103
Type parm,,rs,y,k6fil=1.e-10 $ filter for throwing away small terms
$ in loads due to k6 and grid point energy.
Type parm,,char8,y,k6out='some' $
$ Value     Action
$ some      Print grid point energy only.  (default)
$ lots      Print g. p. energy, g. p.loads, and ESE data with and w/0 
$             k6 effects.
call dbfetch /kgg6,,,,/seid/0/0/0/0 $
mpyad kgg6,ug,/p6gi $ loads due to k6rot
add ug,p6gi/k6enrgy//0.5/1 $
if (k6out='lots') then $
  message //'loads from elements due to k6rot effects' $
  matgpr gpls,uset,sils,p6gi//'h'/'g'//k6fil $ suppress small numbers
endif $
norm k6enrgy/scr6///s,n,k6max $
message //'grid point energy due to k6rot effects, maximum is'/
  k6max $
matgpr gpls,uset,sils,k6enrgy//'h'/'g'//k6fil $ suppress small numbers

compile sedrcvr list $
$alter 604 $ after ofp for all energy
alter 'ENDIF $ GPFDR AND'
Type parm,,char8,y,k6out='some' $
if (k6out='lots') then $
  call dbfetch /kelmdiff,,,,/seid/0/0/0/0 $
  GPFDR    CASEDR,UG,KELMdiff,KDICT,ECTS,EQEXINS,GPECT,PJ1,QG,
    BGPDTN,OL2,CSTMS,VELEM,PTELEM,QMG,NFDICT,FENLR,                     
    MELM,MDICT,BELM,BDICT/                                              
    ONRGY6,OGPFB6,OEKE6,OEDE6/APP2/TINY/XFLAG/                          
    CYCFLG/WTMASS $          
  Message //'element strain energy due to k6rot effects only' $                                           
  Ofp onrgy6// $
Endif $
$ end k6ese alter package