$
$     updated 9-28-99  -  111_by_mode.v707
$ 
$ output-by-mode-111a.v707 - allows data recovery by mode in SOL 111
$
$ beware of the large volume of output from this alter - full data 
$   recovery output will be presented for each mode in the system
$   followed by the standard output.
$
echooff $
$
$     THIS ALTER IS CONFIDENTIAL AND A TRADE SECRET OF THE 
$     MSC.SOFTWARE CORP.  THE RECEIPT OR POSSESSION OF
$     THIS ALTER DOES NOT CONVEY ANY RIGHTS TO REPRODUCE OR
$     DISCLOSE ITS CONTENTS, OR TO MANUFACTURE, USE, OR SELL
$     ANYTHING HEREIN, IN WHOLE OR IN PART, WITHOUT THE 
$     SPECIFIC WRITTEN CONSENT OF THE MSC.SOFTWARE CORPORATION.                                
$
$
$
compile semfreq, list
$
alter 'call.*super3'(,-1) $ insert before call to super3
$
$ ULH2: SOLUTION IN MODAL COORD
$
$matprn ulf,uhf1// $
equivx   uhf1/uhfx/-1 $ save total solution
$
$ RETRIEVES WORD2 FROM TRAILER OF Ulf WHICH IS THE NO OF MODES
$ INSERTING THAT IN nmodes
$
PARAML   uhfx//'trailer'/2/s,n,nmodes $
$message //'nmodes = '/nmodes $                            
$matprn   uhfx/ $
$
$ INITIALIZE knt, THE LOOP COUNTER, AND I1
$
type parm,,i,n,knt=1,i1 $
$
$ REPETITION FOR ALL MODES
$
knt = 1 $
$
do while (knt<=nmodes) $
   i1=knt-1 $
$
$ BUILDS A PARTITIONING VECTOR rp (1,0,0,0) FOR MODE 1
$ AND (0,1,0,0) FOR SECOND ETC...
$ 5.4.-104 OF V66A UM
$
   matgen   ,/rp/6/nmodes/i1/1 $
$ 
$ GETS THE knt-th ROW OF MATRIX UH1 AND CALLS IT uhi
$ 
   partn    uhfx,,rp/,uhi,,/1 $ extract single modal solution at row=knt
$   delete   /uh,,,, $ avoid output twice
$
$ PREPARES A MATRIX WITH ONE ROW FULL AND THE REMAINING ZEROES
$
   merge ,  ,uhi,,,,rp/uhf2/1 $ pad modal solution at other rows
   message  //' ' $
   message  //' begin contribution of mode='/knt $
   message  //' ' $
$   matprn   uhf2/ $
CALL SUPER3  CASECC  ,CASEF   ,ULF     ,FOL1    ,PGF1    ,
                     ,FRL     ,LAMA    ,UHF2    ,DLT     ,
                     ,        ,        ,        ,        ,
                     ,PCDB    ,XYCDB   ,POSTCDB ,        ,
             EMAP    ,MAPS    ,EQEXINS ,PVTS    ,CASES   ,
             SLT     ,ETT     ,GOT     ,GOQ     ,        ,
                     ,        ,        ,        ,GPLS    ,
             USET    ,SILS    ,PJ      ,EDTS    ,YS      ,
             GM      ,        ,KFS     ,KSS     ,QR      ,
                     ,        ,        ,MAR     ,MEA     ,
             DYNAMICS,BGPDTS  ,CSTMS   ,MPTS    ,DIT     ,
             EST     ,GEOM2S  ,GEOM3S  ,ECTS    ,EPTS    ,
             INDTA   ,        ,        ,GPECT   ,        ,
                     ,DITID   ,PVTBC   ,SCSTM   ,        ,
                     ,GEOM4S  ,PG      ,        ,        ,
                     ,EPT     ,MPT     ,GEOM1   ,GEOM2   ,
             GEOM3   ,GEOM4   ,        ,        ,        ,
                     ,        ,MEDGE   ,VIEWTB  ,        ,
             BGPDTVU ,GPSNTS  ,PVT     ,DEQATN  ,DEQIND  ,
             GDNTAB  ,OINT    ,PELSETS ,KSF     ,KMG     ,
             MMG     ,MSF     ,BMG     ,BSF     ,K4MG    ,
             K4SF    ,        ,        ,        ,        ,
                     ,        ,QSGF    ,QMGF    ,EHT     ,
             GEOM1S  ,        ,        ,        ,        ,
                     ,        ,MATPOOL ,        ,        ,
             FOLT    ,        ,        ,        ,        /
             UPF     ,QPFx    ,QMPFx   ,        ,IUG1x   ,
             IQG1x   ,IEF1x   ,IES1x   ,IEE1x   ,IUG2x   ,
             IQG2x   ,IEF2x   ,IES2x   ,IEE2x  /
             APP     /APP1    /RSONLY  /FALSE   /FALSE   /
             FALSE   /DROPT   /FS      /S,PFILE /S,CARDNO/
             0       /FALSE   /0       /PEXIST  /ADPTINDX/
             TRUE    /FREQDEP /FALSE   /DLOOP   /KDIFF   /
             SOLTYP  /FALSE   /FALSE   /FALSE   $
$
delete /UPFx,QPFx,QMPFx,IUG1x,    $
delete /IQG1x,IEF1x,IES1x,IEE1x,IUG2x    $
delete /IQG2x,IEF2x,IES2x,IEE2x, $
$
   knt=knt+1 $
enddo $
$
message //' ' $
message //'the following output is the standard output' $
message //'it contains the contributions of all modes' $
message //' ' $
$
endalter $
echoon $
$