$
$     THIS ALTER IS CONFIDENTIAL AND A TRADE SECRET OF THE 
$     MSC.Software CORP.  THE RECEIPT OR POSSESSION OF
$     THIS ALTER DOES NOT CONVEY ANY RIGHTS TO REPRODUCE OR
$     DISCLOSE ITS CONTENTS, OR TO MANUFACTURE, USE, OR SELL
$     ANYTHING HEREIN, IN WHOLE OR IN PART, WITHOUT THE 
$     SPECIFIC WRITTEN CONSENT OF THE MSC.Software CORPORATION.                                
$
$
$     update 3-2-98  for v70.5
$
$     updated 6-5-97 
$
$
$     appenda.v69 -  updated for v69 -- 9-25-96
$
$  updated for system built on on 3-14-95   VERSION 68.2 
$
$
$ BEGINNING OF DMAP ALTER TO APPEND EIGENSOLUTIONS
$
$   BASED LOOSELY ON RF3D2 - AUG 1991 - V67 MSC/NASTRAN
$
$
$ CASE CONTROL INPUT
$      NEW METHOD ID REQUEST
$
$ BULK DATA INPUT
$      NEW EIGR OR EIGRL DATA
$
$      METHOD USED MUST BE INV, SINV, OR LANCZOS
$
$      PARAMETER APPEN - FORCES EXECUTION OF THIS DMAP ALTER
$             IF APPEN <=0 THEN THE RUN IS A NORMAL RUN
$             IF APPEN  >1 THEN APPEND IS THE VERSION NUMBER TO
$                           GET THE OLD EIGENVALUE SOLUTION FROM
$
$     TWO EIGENVALUE SUMMARY TABLES WILL BE PRINTED. THE FIRST WILL
$     ONLY REFLECT ROOTS FOUND DURING THE CURRENT RUN. THE SECOND WILL
$     CONTAIN THE COMBINED EIGENVALUES. THE EIGENVECTORS WILL
$     INCLUDE RESULTS FROM THE PREVIOUS RUN.
$
$  NOTE!!!!! THIS DMAP DOES NOT CHECK FOR DUPLICATE OR MISSED MODES. IT
$      WILL ONLY APPEND THE RESULTS OF ONE SOLUTION ONTO ANOTHER.
$
$
echooff $
COMPILE MODERS $
ALTER 2
TYPE PARM,,I,Y,APPEN=0 $
FILE LAMA1=APPEND/PHIA1=APPEND $
$ALTER 104 $
$alter 'endif.*\$.*lanczos.*\>.*-1'
alter 'read.*kxx.*mxx' $
IF (APPEN > 0) THEN $
  MESSAGE //' APPENDING THIS EIGENSOLUTION ONTO '/
            'THE SOLUTION FROM VERSION'/APPEN $
  MESSAGE //' THE FOLLOWING TABLE CONTAINS THE MODES FOUND IN THIS RUN' $
ENDIF $
$ALTER 117 $ Before return
alter 'return'(1,-1)
IF (APPEN > 0) THEN $ APPENDING EIGENSOLUTIONS
$
$ GET OLD EIGENVECTORS AND EIGENVALUES
$
  DBVIEW OLDEIG=LAMA (WHERE VERSION = APPEN AND WILDCARD=TRUE) $
  DBVIEW OLDVEC=PHA (WHERE VERSION = APPEN AND WILDCARD=TRUE) $
$  TABPRT OLDEIG// $
$  MATPRN OLDVEC// $
  LAMX, ,LAMA/LMAT/-1 $
  LAMX, ,OLDEIG/OLDLMAT/-1 $
  MATGEN ,/COL34/6/5/2/2/1 $ COLUMN PARTITIONING VECTOR
  MATGEN ,/ROW13/6/3//1/1/1 $ ROW MERGING VECTOR
  PARTN OLDLMAT,COL34,/o1,o2,OLDMAT1,o4/1 $
  PARTN LMAT,COL34,/m1,m2,MAT1,m4/1 $
  TRNSP OLDMAT1/OLDMAT $
  TRNSP MAT1/MAT $
$
$ APPEND THE TWO EIGENSOLUTIONS - IF CHECKING FOR DUPLICATE MODES IS
$    DESIRED, IT SHOULD BE DONE HERE
$
  APPEND OLDMAT,MAT/LAMA1 $
  MERGE, ,LAMA1,,,,ROW13/LAMA2/1 $
  LAMX LAMA2,/NEWLAMA $
  APPEND OLDVEC,PHA/PHIA1 $ APPEND EIGENVECTORS
  PARAML PHIA1//'TRAILER'/1/S,N,NEIGV $ GET CORRECT NUMBER OF EIGENVECTORS
  MESSAGE //' NUMBER OF EIGENVECTORS AFTER APPEND ='/NEIGV $
  MESSAGE //' FOLLOWING EIGENVALUE SUMMARY CONTAINS COMBINED MODES' $
$
$ REPLACE THE NEW EIGENSOLUTION WITH THE TOTAL EIGENSOLUTION
$
  EQUIVX NEWLAMA/LAMA/ALWAYS $
  EQUIVX PHIA1/PHA/ALWAYS $
  OFP LAMA// $
ENDIF $
$  
echoon $