$
$     THIS ALTER IS CONFIDENTIAL AND A TRADE SECRET OF THE 
$     MSC.Software CORP.  THE RECEIPT OR POSSESSION OF
$     THIS ALTER DOES NOT CONVEY ANY RIGHTS TO REPRODUCE OR
$     DISCLOSE ITS CONTENTS, OR TO MANUFACTURE, USE, OR SELL
$     ANYTHING HEREIN, IN WHOLE OR IN PART, WITHOUT THE 
$     SPECIFIC WRITTEN CONSENT OF THE MSC.Software CORPORATION.                                
$
$
$
$       cova.v69 -  updated v69  - 9-25-96
$
$    updated for system built on on 3-14-95   VERSION 68.2  
$    
$    filename - cova.v68   
$
$  ALTER FOR RESPONSE VARIANCES
$
echooff $
COMPILE EXITOPT $
$
$ALTER 16  $
alter 'matprn.*dscm2'(1,-1)
$
$--------------------------------------------------------------------------
$
$  COMPUTE VARIANCES IN RESPONSE DUE TO VARIANCES IN DESIGN VARIABLES
$
$  ALTER FOR VERSION 68, SOL 200
$
$  FORMULAS: COVR = (DSCM2)T * COVD * DSCM2    (T=TRANSPOSE)
$            VAR  = DIAGONAL TERMS OF COVR
$            SDEV = SQRT(VAR)
$
$  WHERE:    COVD  =  COVARIANCE MATRIX OF DESIGN VARIABLES
$                       (USER INPUT VIA DMI, IN ORDER OF DESIGN VARIABLES)
$            DSCM2 =  SENSITIVITY MATRIX
$                       (COMPUTED IN SOL 200)
$            COVR  =  COVARIANCE MATRIX OF RESPONSES
$                       (COMPUTED IN ALTER)
$                       (SEE CORRELATION TABLE FOR ORDER OF RESPONSES)
$                       (CORRELATION TABLE OUTPUT IN SOL 200)
$            VAR   =  VARIANCE OF RESPONSES
$                       (COMPUTED IN ALTER)
$                       (SEE CORRELATION TABLE FOR ORDER OF RESPONSES)
$            SDEV  =  STANDARD DEVIATION OF RESPONSES
$                       (COMPUTED IN ALTER)
$                       (SEE CORRELATION TABLE FOR ORDER OF RESPONSES)
$
$   NOTE:  MATRIX DEFINITIONS PRINTED  U N D E R  EACH MATRIX IN PRINTOUT
$
$
$   USER INPUT:
$
$          Design optimization entries
$          (make sure to use DSCREEN to retain all responses)
$
$          PARAM,OPTEXIT,4    $ Exit after sensitivity
$
$          PARAM,NASPRT,1     $ Data recovery at all cycles
$
$          COVD  (input as DMI)
$          (square matrix of size n by n, where n = no. design variables)
$
$          --- For uncorrelated design variables, the input is the
$              variance of each design variable; i.e.,
$
$               COVD(i,i) = STDEV(i)*STDEV(i)  where STDEV = standard deviation
$
$                Example:
$                 DMI,COVD,0,1,1,0,,n,n  (n = no. of design variables)
$                 DMI,COVD,1,1,v1        (v1 = variance of 1st des. variable)
$                 DMI,COVD,2,2,v2        (v2 = variance of 2nd des. variable)
$                 ...
$                 DMI,COVD,n,n,vn        (vn = variance of nth des. variable)
$
$          --- For CORRELATED design variables, the input is given by
$
$               COVD(i,j) = STDEV(i)*STDEV(j)*P(i,j)
$
$                 where P(i,j) = correlation coefficient (1>P>0)
$                              = 1.0 for fully correlated
$                              = 0.0 for uncorrelated (reduces to above case)
$                 Note: for i =j,  P(i,j) = 1.0 for all cases
$
$               Example:
$                DMI,COVD,0,1,1,0,,n,n
$                DMI,COVD,1,1,s1s1,s1s2p12,s1s3p13,s1s4p14,s1s5p15,+cv1
$                +cv1,s1s6p16,.....
$                DMI,COVD,2,1,s2s1p21,s2s2,s2s3p23,........
$                ...
$                DMI,COVD,n,1,sns1pn1,.....................
$
$                  where  si=STDEV(i), pij=P(i,j)
$
$
$    *******  NOTE!!  *******  NOTE!!  *******  NOTE!!  *******
$
$    Size of DMI is number of INDEPENDENT design variables
$    If have LINKing then must reduce size of DMI to correct size
$
$--------------------------------------------------------------------------
$
$  READ DMI INPUT -- COVD (DESIGN VARIABLE VARIANCES)
$
TYPE DB DMI,DMINDX $
DMIIN  DMI,DMINDX/COVD,,,,,,,,,/S,N,YESCOVD/  $
$
$  MULTIPLY (DSCM2)TRANS * COVD = TMP1
$
MPYAD  DSCM2,COVD,/ TMP1 /1///$
$
$  MULTIPLY TMP1 * DSCM2 = COVR (RESPONSE COVARIANCES)
$
MPYAD  TMP1,DSCM2,/ COVR // $
$
$  PRINT TITLE AND COVD
$
MATPRN  COVD,,,,// $
MESSAGE  // 'VARIANCES OF DESIGN VARIABLES'/  $
MESSAGE  // 'USER INPUT, IN ORDER OF DESIGN VARIABLES'/ $
$
$  PRINT TITLE AND COVR
$
MATPRN  COVR,,,,// $
MESSAGE // 'RESPONSE COVARIANCE MATRIX'/ $
MESSAGE // 'SEE CORRELATION TABLE FOR ORDER OF RESPONSES'/ $
$
$  SET VAR AS VECTOR OF VARIANCES OF RESPONSES
$
DIAGONAL  COVR/VAR/'COLUMN'/ $
$
$  PRINT TITLE AND VAR
$
MATPRN  VAR,,,,// $
MESSAGE // 'VARIANCE OF RESPONSES (DIAGONAL TERMS OF COVR)'/ $
MESSAGE // 'SEE CORRELATION TABLE FOR ORDER OF RESPONSES'/ $
$
$  SET SDEV AS STANDARD DEVIATIONS OF RESPONSES
$
DIAGONAL  COVR/SDEV/'COLUMN'/0.5 $
$
$  PRINT TITLE AND SDEV
$
MATPRN  SDEV,,,,// $
MESSAGE // 'STANDARD DEVIATION OF RESPONSES'/ $
MESSAGE // 'SEE CORRELATION TABLE FOR ORDER OF RESPONSES'/ $
$
ENDALTER
echoon $