$
$     THIS ALTER IS CONFIDENTIAL AND A TRADE SECRET OF THE 
$     MSC.Software CORP.  THE RECEIPT OR POSSESSION OF
$     THIS ALTER DOES NOT CONVEY ANY RIGHTS TO REPRODUCE OR
$     DISCLOSE ITS CONTENTS, OR TO MANUFACTURE, USE, OR SELL
$     ANYTHING HEREIN, IN WHOLE OR IN PART, WITHOUT THE 
$     SPECIFIC WRITTEN CONSENT OF THE MSC.Software CORPORATION.                                
$
$
echooff $
$
$       gridloca.v69 -  updated for v69 --  9-25-96
$
$       gridloca.v69     -       8-15-96
$
$
$       tested on system built on 3-14-95   VERSION 68.2 
$
$       filename - gridloca.v68
$
$ ALTER TO PRINTOUT THE LOCATION OF GRID POINTS IN THE BASIC COORDINATE
$ SYSTEM, REGARDLESS OF PLACEMENT COORDINATE SYSTEMS DESIGNATED ON THE
$ GRID CARDS.
$
$ NOTE: THIS ALTER PACKAGE DOES NOT RUN THE ENTIRE SOLUTION SEQUENCE!
$       IT IS INTENDED TO BE RUN STANDALONE AND EXITS AFTER PRINTING
$       OUT THE GRID POINT LOCATIONS.
$
$   JIM SWAN, MSC - SOUTHWEST REGIONAL OFFICE
$   OCTOBER 1992
$
$
$
$ REQUIRED EXECUTIVE CONTROL CARDS:
$
$      SOL 103                $ OR ANY STRUCTURED SOLN SEQUENCE
$      INCLUDE 'gridloca.v68' $ CALL UP ALTER PACKAGE
$
$
$ REQUIRED CASE CONTROL CARDS:
$
$      DISP = set_id  $ set_id REFERS TO LIST OF GRIDS USER WANTS
$                     $ TO KNOW LOCATION OF
$
$ REQUIRED BULK DATA CARDS: (NONE)
$
$
COMPILE PHASE0 $
$ALTER 26     $ JUST AFTER GP1 MODULE
alter 'gp1'
$
$
$ USE VECPLOT OPTION 3 TO ADD THE BASIC X,Y,Z LOCATIONS IN BGPDT
$ TO A NULL INPUT MATRIX. OUTPUT BLOCK, NAMED LOCBASIC, HAS BASIC
$ XYZ IN 1ST THREE COLUMNS.
$
PARAML     SIL//'TRAILER'/2/S,N,GDOFS  $  NUMBER OF G-SET DOFS
MATGEN     ,/NULL/7/GDOFS/1            $  GENERATE NULL MATRIX
VECPLOT    NULL,BGPDT,EQEXIN,CSTM,,,,/LOCBASIC///3/ $
$
$ TRICK SDR2 INTO ACCEPTING LOCUSER
SDR2     CASECC,CSTM,,,EQEXIN,SIL,,,BGPDT,,,LOCBASIC,,,,,,/
         ,,OLOCBASC,,,/'STATICS' $
MESSAGE  //' ' $
MESSAGE  //' VALUES PRINTED IN THE DISPLACEMENT TABLE BELOW ARE THE '/
           'GRID LOCATIONS WITH RESPECT TO THE ' $
MESSAGE  //' BASIC COORDINATE SYSTEM.  T1 CORRESPONDS TO BASIC X, T2'/
           ' TO BASIC Y, AND T3 TO BASIC Z' $
MESSAGE  //' ' $
OFP      OLOCBASC// $
$
$ AND THEN
EXIT                $ TERMINATE SOLUTION SEQUENCE EARLY
echoon $